This is intended to be a case-study (for those who are new to VM/370) in How Things Work through the use of a practical systems programming activity: Installing and migrating to new hardware.

1. Read “What Mother Never Told You About VM Maintenance” by Melinda Varian
2. Download the VM/370 SixPack 1.3 Beta 3
3. Install or Build Hercules 4.0 (a.k.a. Hyperion)

Optional:

• Replace Sixpack.cmd with the following (make whatever edits you need). It's a better selector tool for the configurations

sixpack.cmd

@echo off
:: This command file launches the VM/370 SixPack.
:: Ensure that the Hercules executable (hercules.exe) is in your path.
setlocal
%~d0
cd %~dp0
path=E:\Engineering\SDL.hyperion\hyperion\msvc.sz.AMD64.bin;%PATH%
 
:Options
cls
Echo :: 
Echo :: %Date% %Time% - %~dpf0
Echo :: 
Echo :: VM/370 R6 "SixPack" version 1.3 Beta 3
Echo :: 
Echo ::  Options: 3350 Configuration [5]
Echo ::           3380 Configuration [8]
Echo ::           VM/370 Window      [V]
Echo ::           Prompt             [P]
Echo ::           Exit               [X]
Echo :: 
 
:Choices
CHOICE /C 58VPX /M "Select Option: "
IF %ERRORLEVEL% EQU 5 exit
IF %ERRORLEVEL% EQU 4 goto :EndProc
IF %ERRORLEVEL% EQU 3 goto :SelectLOCALVMTerm
IF %ERRORLEVEL% EQU 2 set _configFile=sixpack.3380.conf
IF %ERRORLEVEL% EQU 1 set _configFile=sixpack.3350.conf
IF .%_configFile% EQU . GOTO :Choices
 
start hercules -f %_configFile% > Log.txt
goto :Options
 
:SelectLOCALVMTerm
cls
Echo :: 
Echo :: %Date% %Time% - %~dpf0
Echo :: 
Echo :: WC3270 Terminal Options - Local VM/370
Echo :: 
Echo ::    WC3270 CMD Window         [W]
Echo ::     80x24 3278 Model 2       [2]
Echo ::     80x32 3278 Model 3       [3]
Echo ::     80x43 3278 Model 4       [4]
Echo ::    132x27 3278 Model 5       [5]
Echo ::           Return             [R]
Echo ::           Exit               [X]
Echo :: 
 
 
cd WC3270
:: Now start the 3270 emulator.
:: Feel free to replace this with your preferred terminal emulation program.
CHOICE /C W2345RX /M "Select Option: "
IF %ERRORLEVEL% EQU 7 Exit
IF %ERRORLEVEL% EQU 6 goto :WCReturn
IF %ERRORLEVEL% EQU 5 start wc3270.exe -keymap 3270 -title "VM 3270 Model 5" Model5.wc3270
IF %ERRORLEVEL% EQU 4 start wc3270.exe -keymap 3270 -title "VM 3270 Model 4" Model4.wc3270
IF %ERRORLEVEL% EQU 3 start wc3270.exe -keymap 3270 -title "VM 3270 Model 3" Model3.wc3270
IF %ERRORLEVEL% EQU 2 start wc3270.exe -keymap 3270 -title "VM 3270 Model 2" Model2.wc3270
IF %ERRORLEVEL% EQU 1 start cmd.exe /k "cd E:\Emulation\VM370.6Pack.1.3\WC3270"
goto :SelectLOCALVMTerm
 
:WCReturn
cd ..
goto :Options
 
:EndProc
endlocal
cls
Echo :: Environment restored to default
Prompt $P$_$N$G